ERC20.sol 11 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312
  1. // SPDX-License-Identifier: MIT
  2. // OpenZeppelin Contracts (last updated v5.2.0) (token/ERC20/ERC20.sol)
  3. pragma solidity ^0.8.20;
  4. import {IERC20} from "./IERC20.sol";
  5. import {IERC20Metadata} from "./extensions/IERC20Metadata.sol";
  6. import {Context} from "../../utils/Context.sol";
  7. import {IERC20Errors} from "../../interfaces/draft-IERC6093.sol";
  8. /**
  9. * @dev Implementation of the {IERC20} interface.
  10. *
  11. * This implementation is agnostic to the way tokens are created. This means
  12. * that a supply mechanism has to be added in a derived contract using {_mint}.
  13. *
  14. * TIP: For a detailed writeup see our guide
  15. * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
  16. * to implement supply mechanisms].
  17. *
  18. * The default value of {decimals} is 18. To change this, you should override
  19. * this function so it returns a different value.
  20. *
  21. * We have followed general OpenZeppelin Contracts guidelines: functions revert
  22. * instead returning `false` on failure. This behavior is nonetheless
  23. * conventional and does not conflict with the expectations of ERC-20
  24. * applications.
  25. */
  26. abstract contract ERC20 is Context, IERC20, IERC20Metadata, IERC20Errors {
  27. mapping(address account => uint256) private _balances;
  28. mapping(address account => mapping(address spender => uint256)) private _allowances;
  29. uint256 private _totalSupply;
  30. string private _name;
  31. string private _symbol;
  32. /**
  33. * @dev Sets the values for {name} and {symbol}.
  34. *
  35. * All two of these values are immutable: they can only be set once during
  36. * construction.
  37. */
  38. constructor(string memory name_, string memory symbol_) {
  39. _name = name_;
  40. _symbol = symbol_;
  41. }
  42. /**
  43. * @dev Returns the name of the token.
  44. */
  45. function name() public view virtual returns (string memory) {
  46. return _name;
  47. }
  48. /**
  49. * @dev Returns the symbol of the token, usually a shorter version of the
  50. * name.
  51. */
  52. function symbol() public view virtual returns (string memory) {
  53. return _symbol;
  54. }
  55. /**
  56. * @dev Returns the number of decimals used to get its user representation.
  57. * For example, if `decimals` equals `2`, a balance of `505` tokens should
  58. * be displayed to a user as `5.05` (`505 / 10 ** 2`).
  59. *
  60. * Tokens usually opt for a value of 18, imitating the relationship between
  61. * Ether and Wei. This is the default value returned by this function, unless
  62. * it's overridden.
  63. *
  64. * NOTE: This information is only used for _display_ purposes: it in
  65. * no way affects any of the arithmetic of the contract, including
  66. * {IERC20-balanceOf} and {IERC20-transfer}.
  67. */
  68. function decimals() public view virtual returns (uint8) {
  69. return 18;
  70. }
  71. /**
  72. * @dev See {IERC20-totalSupply}.
  73. */
  74. function totalSupply() public view virtual returns (uint256) {
  75. return _totalSupply;
  76. }
  77. /**
  78. * @dev See {IERC20-balanceOf}.
  79. */
  80. function balanceOf(address account) public view virtual returns (uint256) {
  81. return _balances[account];
  82. }
  83. /**
  84. * @dev See {IERC20-transfer}.
  85. *
  86. * Requirements:
  87. *
  88. * - `to` cannot be the zero address.
  89. * - the caller must have a balance of at least `value`.
  90. */
  91. function transfer(address to, uint256 value) public virtual returns (bool) {
  92. address owner = _msgSender();
  93. _transfer(owner, to, value);
  94. return true;
  95. }
  96. /**
  97. * @dev See {IERC20-allowance}.
  98. */
  99. function allowance(address owner, address spender) public view virtual returns (uint256) {
  100. return _allowances[owner][spender];
  101. }
  102. /**
  103. * @dev See {IERC20-approve}.
  104. *
  105. * NOTE: If `value` is the maximum `uint256`, the allowance is not updated on
  106. * `transferFrom`. This is semantically equivalent to an infinite approval.
  107. *
  108. * Requirements:
  109. *
  110. * - `spender` cannot be the zero address.
  111. */
  112. function approve(address spender, uint256 value) public virtual returns (bool) {
  113. address owner = _msgSender();
  114. _approve(owner, spender, value);
  115. return true;
  116. }
  117. /**
  118. * @dev See {IERC20-transferFrom}.
  119. *
  120. * Skips emitting an {Approval} event indicating an allowance update. This is not
  121. * required by the ERC. See {xref-ERC20-_approve-address-address-uint256-bool-}[_approve].
  122. *
  123. * NOTE: Does not update the allowance if the current allowance
  124. * is the maximum `uint256`.
  125. *
  126. * Requirements:
  127. *
  128. * - `from` and `to` cannot be the zero address.
  129. * - `from` must have a balance of at least `value`.
  130. * - the caller must have allowance for ``from``'s tokens of at least
  131. * `value`.
  132. */
  133. function transferFrom(address from, address to, uint256 value) public virtual returns (bool) {
  134. address spender = _msgSender();
  135. _spendAllowance(from, spender, value);
  136. _transfer(from, to, value);
  137. return true;
  138. }
  139. /**
  140. * @dev Moves a `value` amount of tokens from `from` to `to`.
  141. *
  142. * This internal function is equivalent to {transfer}, and can be used to
  143. * e.g. implement automatic token fees, slashing mechanisms, etc.
  144. *
  145. * Emits a {Transfer} event.
  146. *
  147. * NOTE: This function is not virtual, {_update} should be overridden instead.
  148. */
  149. function _transfer(address from, address to, uint256 value) internal {
  150. if (from == address(0)) {
  151. revert ERC20InvalidSender(address(0));
  152. }
  153. if (to == address(0)) {
  154. revert ERC20InvalidReceiver(address(0));
  155. }
  156. _update(from, to, value);
  157. }
  158. /**
  159. * @dev Transfers a `value` amount of tokens from `from` to `to`, or alternatively mints (or burns) if `from`
  160. * (or `to`) is the zero address. All customizations to transfers, mints, and burns should be done by overriding
  161. * this function.
  162. *
  163. * Emits a {Transfer} event.
  164. */
  165. function _update(address from, address to, uint256 value) internal virtual {
  166. if (from == address(0)) {
  167. // Overflow check required: The rest of the code assumes that totalSupply never overflows
  168. _totalSupply += value;
  169. } else {
  170. uint256 fromBalance = _balances[from];
  171. if (fromBalance < value) {
  172. revert ERC20InsufficientBalance(from, fromBalance, value);
  173. }
  174. unchecked {
  175. // Overflow not possible: value <= fromBalance <= totalSupply.
  176. _balances[from] = fromBalance - value;
  177. }
  178. }
  179. if (to == address(0)) {
  180. unchecked {
  181. // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
  182. _totalSupply -= value;
  183. }
  184. } else {
  185. unchecked {
  186. // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
  187. _balances[to] += value;
  188. }
  189. }
  190. emit Transfer(from, to, value);
  191. }
  192. /**
  193. * @dev Creates a `value` amount of tokens and assigns them to `account`, by transferring it from address(0).
  194. * Relies on the `_update` mechanism
  195. *
  196. * Emits a {Transfer} event with `from` set to the zero address.
  197. *
  198. * NOTE: This function is not virtual, {_update} should be overridden instead.
  199. */
  200. function _mint(address account, uint256 value) internal {
  201. if (account == address(0)) {
  202. revert ERC20InvalidReceiver(address(0));
  203. }
  204. _update(address(0), account, value);
  205. }
  206. /**
  207. * @dev Destroys a `value` amount of tokens from `account`, lowering the total supply.
  208. * Relies on the `_update` mechanism.
  209. *
  210. * Emits a {Transfer} event with `to` set to the zero address.
  211. *
  212. * NOTE: This function is not virtual, {_update} should be overridden instead
  213. */
  214. function _burn(address account, uint256 value) internal {
  215. if (account == address(0)) {
  216. revert ERC20InvalidSender(address(0));
  217. }
  218. _update(account, address(0), value);
  219. }
  220. /**
  221. * @dev Sets `value` as the allowance of `spender` over the `owner`'s tokens.
  222. *
  223. * This internal function is equivalent to `approve`, and can be used to
  224. * e.g. set automatic allowances for certain subsystems, etc.
  225. *
  226. * Emits an {Approval} event.
  227. *
  228. * Requirements:
  229. *
  230. * - `owner` cannot be the zero address.
  231. * - `spender` cannot be the zero address.
  232. *
  233. * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
  234. */
  235. function _approve(address owner, address spender, uint256 value) internal {
  236. _approve(owner, spender, value, true);
  237. }
  238. /**
  239. * @dev Variant of {_approve} with an optional flag to enable or disable the {Approval} event.
  240. *
  241. * By default (when calling {_approve}) the flag is set to true. On the other hand, approval changes made by
  242. * `_spendAllowance` during the `transferFrom` operation set the flag to false. This saves gas by not emitting any
  243. * `Approval` event during `transferFrom` operations.
  244. *
  245. * Anyone who wishes to continue emitting `Approval` events on the`transferFrom` operation can force the flag to
  246. * true using the following override:
  247. *
  248. * ```solidity
  249. * function _approve(address owner, address spender, uint256 value, bool) internal virtual override {
  250. * super._approve(owner, spender, value, true);
  251. * }
  252. * ```
  253. *
  254. * Requirements are the same as {_approve}.
  255. */
  256. function _approve(address owner, address spender, uint256 value, bool emitEvent) internal virtual {
  257. if (owner == address(0)) {
  258. revert ERC20InvalidApprover(address(0));
  259. }
  260. if (spender == address(0)) {
  261. revert ERC20InvalidSpender(address(0));
  262. }
  263. _allowances[owner][spender] = value;
  264. if (emitEvent) {
  265. emit Approval(owner, spender, value);
  266. }
  267. }
  268. /**
  269. * @dev Updates `owner`'s allowance for `spender` based on spent `value`.
  270. *
  271. * Does not update the allowance value in case of infinite allowance.
  272. * Revert if not enough allowance is available.
  273. *
  274. * Does not emit an {Approval} event.
  275. */
  276. function _spendAllowance(address owner, address spender, uint256 value) internal virtual {
  277. uint256 currentAllowance = allowance(owner, spender);
  278. if (currentAllowance < type(uint256).max) {
  279. if (currentAllowance < value) {
  280. revert ERC20InsufficientAllowance(spender, currentAllowance, value);
  281. }
  282. unchecked {
  283. _approve(owner, spender, currentAllowance - value, false);
  284. }
  285. }
  286. }
  287. }